Ultrasensor Theremin V2 : 2-Ther-e, 2-Min

The general idea behind getting the second theremin to work was pretty simple---pop in a second ultrasensor in a different place, and map its signal to volume. Luckily, unlike the standard tone function, there's a library called Volume3 by Connor Nishijima that lets you set both the pitch and volume of an output speaker. Here's what my hardware setup looked like:

I tried for a while to parallelize the process of sending and receiving the ultrasensor signals by putting them into a class and creating "phases" where they wait until a certain time has passed to perform the next operation, but this didn't really work. Eventually, I just tried to make a basic ultrasensor class and read each of there signals in the inner loop, and this worked totally fine. I guess that they're sent and received fast enough that it doesn't matter whether they're parallelized. Another lesson: always try the dumb solution first in case it just works out.

The only other notable change is that I was able to get a more smooth transition between pitches by changing the map function to work on floats. Ints basically truncated all the information between scales, so I could only map very specific distance measurements to pitches. Finally, I just found a box of clay in one of the bins and taped an ultrasensor to each side to get my final prototype:

Here's my final code:

                
#include "Volume3.h" // Include the Volume library
#define speakerPin 9

// Ultrasensor class
class ultraSensor {
    int trigPin;
    int echoPin;
    // Tells where we should stop growing the signal (sensitivity parameter)
    float highBound;

    public:
    ultraSensor(int tPin, int ePin, float bound) {
        trigPin = tPin;
        echoPin = ePin;
        pinMode(trigPin, OUTPUT);
        pinMode(echoPin, INPUT);
        highBound = bound;
    }

    // Collect a distance reading from the ultrasensor, in cm (I think)
    float readTone() {
        digitalWrite(trigPin, LOW);
        delayMicroseconds(2);
        digitalWrite(trigPin, HIGH);
        delayMicroseconds(10);
        digitalWrite(trigPin, LOW);
        float duration = pulseIn(echoPin, HIGH);
        float distance = duration * .034  / 2;

        // Truncate the reading above a certain threshold
        if (distance > highBound) {
        distance = highBound;
        }

        return(float(distance));
    }
};

// This is just map, but it doesn't truncate floats
long float_map(float x, float in_min, float in_max, float out_min, float out_max)
{
    return (x - in_min) * (out_max - out_min) / (in_max - in_min) + out_min;
}

// Define one ultrasensor looking for pitch, and another looking for volume
float volBound = 10.0;
float pitchBound = 50.0;
ultraSensor pitchSensor(3,5, pitchBound);
ultraSensor volSensor(10, 11, volBound);

void setup() {
}

void loop() {
    // Grab the distance measurements from each sensor
    float pitch_raw = pitchSensor.readTone();
    float vol_raw = volSensor.readTone();

    // Map each distance to a valid pitch or volume
    float pitch = float_map(pitch_raw, 0, pitchBound, 200, 1500);
    float volume = float_map(vol_raw, 0, volBound, 0, 1023);

    vol.tone(speakerPin, pitch, volume);
    // vol.tone doesn't have a time parameter like the normal tone() function, so you have to add some delay for the sound to persist
    delay(2);
}